home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / 86xx / 8612.d64 / skaltrans (allg) (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  2KB  |  76 lines
  1. 10 REM ********* TRANSFORMATIONEN TEST ************
  2. 15 A=0:B=0:C=0:D=0:I=0:J=0:K=0:L=0:XU=0:XO=64:YU=0:YO=40:A$=""
  3. 20 DIM P(2,6,3),M(1,3,3)
  4. 25 REM -------- BELEGEN DER PUNKTEMATRIX ---------
  5. 30 DATA 0,0,15,0,15,9,7.5,13,0,9
  6. 35 FOR I=1 TO 5
  7. 40 :FORJ=1TO2
  8. 45 ::READ P(0,I,J)
  9. 50 :NEXTJ
  10. 55 :P(0,I,3)=1
  11. 60 NEXTI
  12. 65 P(0,6,1)=P(0,1,1):P(0,6,2)=P(0,1,2):P(0,6,3)=P(0,1,3)
  13. 70 REM -------- BELEGEN DER MATRIX M(1,..) -------
  14. 75 M(1,1,1)=319/(XO-XU):M(1,2,2)=-199/(YO-YU):M(1,3,3)=1
  15. 80 FORI=1TO3
  16. 85 :FORJ=1TO3
  17. 90 ::IFI=JTHEN100
  18. 95 ::M(1,I,J)=0
  19. 100 :NEXTJ
  20. 105 NEXTI
  21. 110 M(1,3,2)=199
  22. 200 REM ------- HAUPTPROGRAMM - SKALTRANS ------
  23. 205 REM --- BELEGEN VON M(0,...) --------
  24. 210 FOR I = 1 TO 3
  25. 215 :FOR J = 1 TO 3
  26. 220 ::M(0,I,J)=0
  27. 225 :NEXT J
  28. 230 NEXT I
  29. 235 M(0,1,1)=0.1:M(0,2,2)=0.1:M(0,3,3)=1
  30. 240 GOSUB655
  31. 245 REM --- ZENTRALE SCHLEIFE -----------
  32. 250 FOR L = 1 TO 10
  33. 255 :M(0,1,1)=M(0,1,1)+.1:M(0,2,2)=M(0,2,2)+.1
  34. 260 :B=0:A=1:D=0:GOSUB550
  35. 265 :B=1:A=2:D=1:GOSUB550
  36. 270 :GOSUB630
  37. 275 NEXT L
  38. 280 GOSUB670
  39. 285 END
  40. 500 REM +++++++++++ UP MATRIMULT +++++++++++++
  41. 505 REM EINE 3,3-MATRIX M UND EINE 6,3-MATRIX
  42. 510 REM P WERDEN MITEINANDER MULTIPLIZIERT.
  43. 515 REM I,J,K = SCHLEIFENVARIABLE
  44. 520 REM C     = ZWISCHENWERT
  45. 525 REM A UND B NUMMER DER 6,3-MATRIX P:
  46. 530 REM  B     = AUSGANGSMATRIX
  47. 535 REM  A     = ERGEBNISMATRIX
  48. 540 REM D IST DIE NUMMER DER 3,3-MATRIX M
  49. 545 REM ++++++++++++++++++++++++++++++++++++++
  50. 550 FORI=1TO6
  51. 555 :FORJ=1TO3
  52. 560 ::C=0
  53. 565 ::FORK=1TO3
  54. 570 :::C=C+P(B,I,K)*M(D,K,J)
  55. 575 ::NEXTK:P(A,I,J)=C
  56. 580 :NEXTJ
  57. 585 NEXTI
  58. 590 RETURN
  59. 600 REM ++++++++ UP ZEICHNEN (ALLG) +++
  60. 605 REM I  = SCHLEIFENVARIABLE
  61. 610 REM A$ = VARIABLE FUER TASTENDRUCK
  62. 615 REM P IST DIE 6,3-PUNKTEMATRIX
  63. 620 REM  A IST DIE NUMMER DIESER MATRIX
  64. 625 REM +++++++++++++++++++++++++++++++
  65. 630 FORI=1TO5
  66. 635 :LINIE(P(A,I,1),P(A,I,2),P(A,I+1,1),P(A,I+1,2))
  67. 640 NEXTI
  68. 645 RETURN
  69. 650 REM --- GRAFIK EINSCHALTEN --------
  70. 655 INIT:START
  71. 660 RETURN
  72. 665 REM --- GRAFIK AUSSCHALTEN --------
  73. 670 SHOW
  74. 675 NORMAL
  75. 680 RETURN
  76.